@echo off
rem LosaDev 2014: creates LosaGame, LosaGame_log, LosaLogData and Backup and fills them.
rem Usage: setup-db.bat [server]        (default .\SQLEXPRESS; Windows login with sysadmin rights)
rem Needs sqlcmd (SQL Server command line tools) on PATH. Asks for the DB agent password.
rem Logs go to logs\. Existing databases are kept; scripts that already ran give "already exists" errors.
setlocal
cd /d "%~dp0"
set SRV=%~1
if "%SRV%"=="" set SRV=.\SQLEXPRESS
if "%DB_COLLATE%"=="" set DB_COLLATE=DEFAULT
set /p DB_PASSWORD=Password for the DB agent logins (same as PW= in ls_dbagent.ini):
set /p ENCODE_KEY=Encode key, 15 characters: 
if "%DB_PASSWORD%"=="" echo No password given. & exit /b 1
if not exist logs mkdir logs
call :run 00_create_databases.sql
call :run 01_logins.sql
call :run 02_LosaGame_log.sql
call :run 03_LosaGame_tables.sql
call :run 04_LosaGame_procs.sql
call :run 05_LosaGame_etc.sql
call :run 06_LosaGame_stubs.sql
call :run 07_LosaLogData_stubs.sql
call :run 08_fixes_and_accounts.sql
call :run 09_param_fixes.sql
call :run 10_features_from_2021.sql
call :run 11_first_tournament.sql
call :run 12_core_procs_from_2021.sql
call :run 13_users.sql
findstr /b /c:"Msg " logs\*.log >nul && (echo Some statements failed: search logs\*.log for "Msg ".) || echo Done, no errors.
exit /b 0

:run
echo running %1
sqlcmd -S "%SRV%" -E -I -f 65001 -v DB_COLLATE="%DB_COLLATE%" DB_PASSWORD="%DB_PASSWORD%" ENCODE_KEY="%ENCODE_KEY%" -i "%1" -o "logs\%~n1.log"
exit /b 0